Objekt Drive, kolekce Drives - Příklad

Počet disků na serveru: 4

Zvolte disk:
Výpis zdrojového textu souboru http://www12.brinkster.com:80/mibla/priklady/drives.asp
<!DOCTYPE html PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
<html>
<head>
  <meta http-equiv="Content-Type" content="text/html;charset=windows-1250">
  <title>Jemný úvod do ASP - Objekt Drive, kolekce Drives - Pøíklad</title>
</head>
<body>
     
<h1>Objekt Drive, kolekce Drives - Pøíklad</h1>

<!-- Formuláø -->
<%
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
Set colDrives = objFSO.Drives
Response.Write "Poèet diskù na serveru: " & colDrives.Count & "<BR>"
%>
<BR>
<FORM ACTION="drives.asp" METHOD="post">
  Zvolte disk:
<SELECT name="disk">
<%
  For Each objDrive In colDrives
    If Request.Form("disk") = objDrive.DriveLetter Then
      sel = " selected"
    Else
      sel = ""
    End If
    Response.Write "<OPTION" & sel & ">" & objDrive.DriveLetter & "</OPTION>"
  Next
%>  
</SELECT>
<input type="submit" name="submit" value="Zobrazit podrobnosti">
</FORM>

<!-- Skript na zpracování formuláøe -->

<% 
  If Request.Form("submit") <> "" Then
  'Bylo stisknuto tlaèítko pro odeslání
    'Uložíme si písmeno disku
    disk = Request.Form("disk")
    'Získáme objekt Drive
    Set objDrive = colDrives.Item(CStr(disk))
    'Vypíšeme podrobnosti o disku
    Response.Write "<HR>"
    Response.Write "Podrobnosti o disku <i>" & disk & "</i>:<BR>"
    Response.Write "<TABLE BORDER=""1"">"
    Response.Write "<TR><TD>Oznaèení:<TD>" & objDrive.DriveLetter
    'Zjistíme druh disku
    druh = objDrive.DriveType
    If (druh < 0) Or (druh > 5) Then druh = 0
    druhy = Array("Neznámý", "Vyjímatelný", "Pevný", "Síový", "CD-ROM", "RAM Disk")
    Response.Write "<TR><TD>Druh:<TD>" & druhy(druh)
    'Zjistíme jestli je disk dostupný
    If Not objDrive.IsReady Then
      'Disk není dostupný
      Response.Write "</TABLE>"
      Response.Write "Disk není k dispozici."
    Else
      'Disk je dostupný
      Function Prepocet(velikost)
        'Funkce pro pøepoèet velikostí na vìtší jednotky
        i = 0
        Do While (velikost >= 1024) And (i < 4)
          velikost = velikost / 1024
          i = i + 1
        Loop
        'Výsledek zaokrouhlíme na 2 desetinná místa
        velikost = ((100 * velikost) \ 1) /100
        jednotky = Array("B", "KB", "MB", "GB", "TB")
        'Vrátíme pøepoètenou velikost a její jednotku
        Prepocet = velikost & " " & jednotky(i)
      End Function
      Response.Write "<TR><TD>Souborový systém:<TD>" & objDrive.FileSystem
      Response.Write "<TR><TD>Pojmenování disku:<TD>" & objDrive.VolumeName
      Response.Write "<TR><TD>Celková kapacita:<TD>" & Prepocet(objDrive.TotalSize)
      Response.Write "<TR><TD>Volné místo dostupné uživateli:<TD>" & Prepocet(objDrive.FreeSpace)
      Response.Write "<TR><TD>Cesta:<TD>" & objDrive.Path
      Response.Write "<TR><TD>Koøenová složka:<TD>" & objDrive.RootFolder
      Response.Write "<TR><TD>Sériové èíslo:<TD>" & objDrive.SerialNumber
      Response.Write "<TR><TD>Síová cesta:<TD>" & objDrive.ShareName
      Response.Write "</TABLE>"
    End If
  End If
%>

 
</body>
</html>

Hlavní stránka