Objekt Request

Objekt Request obsahuje metody pro práci s daty obsaženými v HTTP požadavku.

Tento objekt se používá např. pro přístup k datům formulářů.

Metody

Tento objekt poskytuje pouze jednu metodu.

Metoda BinaryRead

Umožňuje přímé čtení dat odeslaných z formuláře, což je vhodné především pro zpracování uploadovaného souboru.

!!Pozor!! Před použitím metody BinaryRead nesmí být použita kolekce Form a před použitím kolekce Form nesmí být použita metoda BinaryRead.

Atributy

Atribut TotalBytes

Obsahuje informaci o počtu bytů v těle HTTP požadavku.

Příklad:

pocet_bytu = Request.TotalBytes
data = Request.BinaryRead(pocet_bytu)

Kolekce

Objekt Request obsahuje několik kolekcí.

Kolekce ClientCertificate

V případě zabezpečeného přístupu (např. technologií SSL) obsahuje tato kolekce informace o digitálním certifikátu klienta.

Pole kolekce ClientCertificate

Přístup k jednotlivým údajům pole Issuer a Subject je možný tak, že k identifikátoru pole přidáme ještě kód z následující tabulky:

Příklad použití:

strOrgName = Request.ClientCertificate("SubjectO")
Response.Write "Organizace uživatele certifikátu: " & strOrgName

Kolekce Cookies

Mechanismus cookies umožňuje webovému serveru ukládat informace (cookies) do souboru na počítači klienta.

Kolekce Request.Cookies slouží ke čtení těchto informací uložených u klienta, pro jejich zápis se používá kolekce Response.Cookies.

Každá cookie může být jednoduchá nebo vícehodnotová.

Jednoduchou cookie přečteme např. příkazem:

datumPosledniNavstevy = Request.Cookies("PoslNavsteva")

Vícehodnotové cookies jsou organizovány jako páry klíč/hodnota a používají se například pro ukládání dat z formuláře. Pro přístup k jednotlivým hodnotám vícehodnotové cookie se používá ještě další nepovinný parametr.

Příklad:

jmeno = Request.Cookies("OsobniUdaje", "Jmeno")
prijmeni = Request.Cookies("OsobniUdaje", "Prijmeni")
Response.Write "Jsme rádi, že se nás " & jmeno & " "
Response.Write prijmeni & " rozhodl opět navštívit :-)"

Prvky kolekce Cookies

Každý prvek kolekce Request.Cookies je opět kolekcí, která má kromě standardních vlastností všech kolekcí navíc ještě atribut HasKeys.

Atribut HasKeys má hodnotu false, pokud jde o jednoduchou cookie. Jde-li o vícehodnotovou cookie, má atribut HasKeys hodnotu true.

Příklad:

For Each objItem In Request.Cookies
  'Procházíme celou kolekci Request.Cookies
  If Request.Cookies(objItem).HasKeys Then
    'Našli jsme vícehodnotovou cookie
    For Each objItemKey In Request.Cookies(objItem)
      'Vypíšeme postupně všechny hodnoty vícehodnotové cookie
      Response.Write objItem & "(" & objItemKey & ") = " & _
        Request.Cookies(objItem)(objItemKey) & "<BR>"
    Next
  Else
    'Našli jsem jednoduchou cookie, vypíšeme její hodnotu
    Response.Write objItem & " = " & Request.Cookies(objItem) & "<BR>"
  End If
Next

Kolekce Form

Každý prvek HTML formuláře může být pojmenován (atribut NAME), po odeslání formuláře jsou zadané hodnoty v ASP přístupné prostřednictvím tohoto jména.

Podle metody odesílání hodnot formuláře (atribut METHOD) jsou hodnoty přístupné přes kolekci Request.Form nebo Request.QueryString.

Příklad:

Nadefinujeme si následující formulář.

<FORM ACTION="registrace.asp" METHOD="post">
  Jméno: <INPUT TYPE="text" NAME="jmeno"><BR>
  Příjmení: <INPUT TYPE="text" NAME="prijmeni"><BR>
  <INPUT TYPE="submit">
</FORM>

Soubor registrace.asp potom bude obsahovat:

...
Response.Write "Jméno: " & Request.Form("jmeno") & "<BR>"
Response.Write "Příjmení: " & Request.Form("prijmeni") & "<BR>"
...

Práce s vícehodnotovými prvky formuláře

Některé prvky formuláře umožňují výběr více hodnot. V tom případě je možné z atributu Count zjistit počet vybraných hodnot.

Příklad:

V souboru request_form.asp si nadefinujeme formulář:

Zaškrtněte všechny jazyky, které znáte:<BR>
<FORM ACTION="request_form.asp" METHOD="post">
  <INPUT TYPE="checkbox" NAME="jazyk" VALUE="Angličtina">Angličtina</INPUT><BR>
  <INPUT TYPE="checkbox" NAME="jazyk" VALUE="Němčina">Němčina</INPUT><BR>
  <INPUT TYPE="checkbox" NAME="jazyk" VALUE="Francouzština">Francouzština</INPUT><BR>
  <INPUT TYPE="checkbox" NAME="jazyk" VALUE="Španělština">Španělština</INPUT><BR>
  <INPUT TYPE="checkbox" NAME="jazyk" VALUE="Italština">Italština</INPUT><BR>
  <INPUT TYPE="submit"><BR>
</FORM>

Kód pro zpracování hodnot zadaných do formuláře bude vypadat následovně (bude ve stejném souboru hned za formulářem):

<%
  If Request.Form("submit") <> "" Then
  'Pokud již byl formulář odeslán, vyhodnotíme počet zaškrtnutých možností
    If Request.Form("jazyk").Count <= 1 Then
      Response.Write "Měl(a) byste na sobě ještě trochu zapracovat."
    Else
      Response.Write "Vaše jazykové znalosti jsou dobré.<BR>"
      Response.Write "Byly zaškrtnuty následující jazyky:<BR><UL>"
      For i = 1 To Request.Form("jazyk").Count
      'Vypíšeme všechny označené možnosti
        Response.Write "<LI>" & Request.Form("jazyk")(i) & "</LI>"
      Next
      Response.Write "</UL>"
    End If
  End If
%>

Kolekce QueryString

Tato kolekce se používá pro práci s daty odeslanými metodou GET, s touto kolekcí se pracuje úplně stejně jako s kolekcí Form. Rozdíl je jen ve způsobu odesílání dat od klienta na server.

Hodnoty z formuláře odesílaného metodou GET se předávají v kocové části URL adresy.

Příklad URL obsahující data z textových polí jmeno a prijmeni:

http://www.nejakyserver.cz/registrace.asp?jmeno=Josef&prijmeni=Svejk

Pro přístup k hodnotě zadané do textového pole jmeno se použije:

jmeno = Request.QueryString("jmeno")

Příklad práce s vícehodnotovými prvky formuláře:

V souboru request_querystring.asp si nadefinujeme formulář:

Zaškrtněte všechny jazyky, které znáte:<BR>
<FORM ACTION="request_querystring.asp" METHOD="get">
  <INPUT TYPE="checkbox" NAME="jazyk" VALUE="Angličtina">Angličtina</INPUT>
  <INPUT TYPE="checkbox" NAME="jazyk" VALUE="Němčina">Němčina</INPUT>
  <INPUT TYPE="checkbox" NAME="jazyk" VALUE="Francouzština">Francouzština</INPUT>
  <INPUT TYPE="checkbox" NAME="jazyk" VALUE="Španělština">Španělština</INPUT>
  <INPUT TYPE="checkbox" NAME="jazyk" VALUE="Italština">Italština</INPUT>
  <INPUT TYPE="submit">
</FORM>

Příklad URL obsahující data odeslaná z tohoto formuláře:

http://www.nejakyserver.cz/anketa.asp?jazyk=Angličtina&jazyk=Španělština

!!!Pozor!!! Uvedený příklad adresy byl zjednodušen. Ve skutečnosti se totiž v URL adrese používají jen 7-bitové kódy znaků, proto se znaky musí překódovávat.

Skript pro zpracování tohoto formuláře bude vypadat následovně:

 <%
  If Request.QueryString("submit") <> "" Then
  'Pokud již byl formulář odeslán, vyhodnotíme počet zaškrtnutých možností
    If Request.QueryString("jazyk") <= 1 Then
      Response.Write "Měl(a) byste na sobě ještě trochu zapracovat."
    Else
      Response.Write "Vaše jazykové znalosti jsou dobré.<BR>"
      Response.Write "Byly zaškrtnuty následující jazyky:<BR><UL>"
      For i = 1 To Request.QueryString("jazyk").Count
        Response.Write "<LI>" & Request.QueryString("jazyk")(i) & "</LI>"
      Next
      Response.Write "</UL>"
    End If
  End If
%>

Kolekce ServerVariables

Kolekce Request.ServerVariables obsahuje všechny HTTP hlavičky odeslané klientem v HTTP požadavku a navíc ještě některé systémové proměnné, týkající se daného webového serveru.

Všechny proměnné jsou pouze pro čtení (tzn. jejich hodnotu nelze měnit).

Hodnotu proměnné zjistíme příkazem:

hodnota = Request.ServerVariables(jméno_proměnné_HTTP) 

Následující tabulka obsahuje seznam proměnných dostupných v kolekci ServerVariables:

Ostatní hlavičky (např. vytvořené metodou Response.AddHeader) jsou přístupné přes název odvozený z původního názvu přidáním prefixu HTTP_ a převedením pomlček na podtržítka.

Pokud by klient v požadavku odeslal například hlavičku Uzivatelska-Hlavicka, zjistíme její hodnotu příkazem:

hodnota = Request.ServerVariables("HTTP_Uzivatelska_Hlavicka")

Při pokusu o načtení neexistující hlavičky je vrácen prázdný řetězec.

Hlavní stránka